SAK 図書館
SAK 図書館
VB oo4o + SQL 応用編5 oo4o 更新 - CreateSql、Refresh
oo4o は、Oracle RDBMS でみ使用可能です。
■CreateSql での更新
・CreateSql でもバインド変数を使用した更新ができる。
■OraSQLStmt メソッド
OraSQLStmt.Refresh (リクエリ)
Set OraSqlStmt = Nothing (OraSQLStmt 破棄)
■OraSQLStmt プロパティ
OraSQLStmt.RecordCount (処理件数)
■CreateSql 定数
Public Const ORASQL_DEFAULT = &H0
Public Const ORASQL_NO_AUTOBIND = &H1
Public Const ORASQL_FAILEXEC = &H2
■現実的なコード例
Option Explicit
'** oo4o 変数宣言
dim OraSession
dim OraDatabase
dim OraSqlStmt
'=======================================================================
' 準備
'=======================================================================
Private Sub Form_Load()
dim dbname as string
dim cnuser as string
'** エラートラップ開始
on local error resume next
'** アイキャッチ表示
'Load FormLogo
'FormLogo.Show
'DoEvents
'// 接続に 10 秒ほどかかるので、「データベース接続中...」などの
'// モードレスダイアログを表示すると良い。
'** サービス、ユーザ設定
dbname = ""
cnuser = "SAK/SAK"
'// Oracle サービス名(別名)、ユーザ・パスワード指定
'** oo4o 接続
Set OraSession = CreateObject("OracleInProcServer.XOraSession")
if err <> 0 then
MsgBox "データベースに接続出来ません。" & chr(10) _
& "CreateObject - Oracle oo4o エラー"
end
end if
Set OraDatabase = OraSession.OpenDatabase(dbname, cnuser, ORADB_DEFAULT)
if err <> 0 then
MsgBox "データベースに接続出来ません。" & chr(10) _
& err & ": " & error
end
end if
'** SQL 作成
Set OraSqlStmt = OraDatabase.CreateSql("insert into sak.テストm " _
& "(キー, データ1, データ2, データ3) values " _
& "(:キー, :データ1, :データ2, :データ3)", ORASQL_DEFAULT)
if OraDatabase.LastServerErr = 1008 then OraDatabase.LastServerErrReset
if err <> 0 or OraDatabase.LastServerErr <> 0 then
MsgBox "SQL 作成に失敗しました。" & chr(10) _
& err & ": " & error & chr(10) _
& "oo4o: " & OraDatabase.LastServerErrText
end
end if
'** パラメタ追加
OraDatabase.Parameters.Add "キー", 0, ORAPARM_INPUT
OraDatabase.Parameters("キー").ServerType = ORATYPE_CHAR
OraDatabase.Parameters.Add "データ1", 0, ORAPARM_INPUT
OraDatabase.Parameters("データ1").ServerType = ORATYPE_NUMBER
OraDatabase.Parameters.Add "データ2", 0, ORAPARM_INPUT
OraDatabase.Parameters("データ2").ServerType = ORATYPE_NUMBER
OraDatabase.Parameters.Add "データ3", 0, ORAPARM_INPUT
OraDatabase.Parameters("データ3").ServerType = ORATYPE_NUMBER
if err <> 0 or OraDatabase.LastServerErr <> 0 then
MsgBox "パラメタ追加に失敗しました。" & chr(10) _
& err & ": " & error & chr(10) _
& "oo4o: " & OraDatabase.LastServerErrText
end
end if
'** アイキャッチ終了
'Unload FormLogo
'// 接続が完了すれば、「データベース接続中...」をクローズする。
'** エラートラップ終了
on local error goto 0
End Sub
'=======================================================================
' 後始末
'=======================================================================
Private Sub Form_Unload(Cancel As Integer)
'** パラメタ解消
OraDatabase.Parameters.Remove "キー"
OraDatabase.Parameters.Remove "データ1"
OraDatabase.Parameters.Remove "データ2"
OraDatabase.Parameters.Remove "データ3"
'** パラメタクエリ解消
Set OraSqlStmt = Nothing
'** oo4o 接続解除
Set OraDatabase = Nothing
Set OraSession = Nothing
End Sub
'=======================================================================
' メイン
'=======================================================================
Private Sub Command1_Click()
'** RDB 処理
if RdbShori(OraDatabase) then
msgbox "RDB 更新正常終了。"
end if
End Sub
'=======================================================================
' RDB 処理
'=======================================================================
private function RdbShori(OraDatabase) as boolean
'** エラーセット
RdbShori = FALSE
'** エラートラップ開始
on local error resume next
'** oo4o エラーリセット
OraDatabase.LastServerErrReset
'** トランザクション開始
OraSession.BeginTrans
'** RDB 処理1
OraDatabase.Parameters("キー").Value = "a001"
OraDatabase.Parameters("データ1").Value = 10
OraDatabase.Parameters("データ2").Value = 20
OraDatabase.Parameters("データ3").Value = 30
OraSqlStmt.Refresh
if err <> 0 or OraDatabase.LastServerErr <> 0 then
OraSession.Rollback
MsgBox "RDB 更新1 に失敗しました。" & chr(10) _
& err & ": " & error & chr(10) _
& "oo4o: " & OraDatabase.LastServerErrText
exit function
end if
'** RDB 処理2
OraDatabase.Parameters("キー").Value = "b002"
OraDatabase.Parameters("データ1").Value = 100
OraDatabase.Parameters("データ2").Value = 200
OraDatabase.Parameters("データ3").Value = 300
OraSqlStmt.Refresh
if err <> 0 or OraDatabase.LastServerErr <> 0 then
OraSession.Rollback
MsgBox "RDB 更新2 に失敗しました。" & chr(10) _
& err & ": " & error & chr(10) _
& "oo4o: " & OraDatabase.LastServerErrText
exit function
end if
'** トランザクション終了
OraSession.CommitTrans
'** エラートラップ終了
on local error goto 0
'** 正常セット
RdbShori = TRUE
end function
■説明
・バラメタの作成と解消は、Form_Load と Form_Unload で実施。
・if OraDatabase.LastServerErr = 1008 then OraDatabase.LastServerErrReset
は、SQL を作るだけに使用した CreateSQL のバインドエラーをリセット。
先にパラメタを追加するとエラーにならないが、SQL が実行されてしまう。
■VB oo4o + SQL 応用編資料
■VB ADO + SQL 応用編資料
■VB RDO + SQL 応用編資料
■SQL 基礎編資料
■SQL 基礎実地編資料
■SQL チューニング編資料
■Oracle PL/SQL 編資料
■PostgreSQL 編、JAVA Servlet、JSP 編資料
■MySQL 編資料
■VB 入門編資料
■VB 基礎編資料
■VB ビジュアル編資料
■VB テクニック編資料
Copyright (C) 1999-2024 Y.SAK