SAK 図書館
SAK 図書館
ASP VB Script oo4o + SQL 応用編9 oo4o ストアドファンクション - PL/SQL
oo4o は、Oracle RDBMS でみ使用可能です。
■ストアドファンクション / ストアドプロシジャ
・ExecuteSql での実行
Dim pret
'** パラメタ追加
session("OraDatabase").Parameters.Add "ret", 0, ORAPARM_OUTPUT
set pret = session("OraDatabase").Parameters("ret")
pret.ServerType = ORATYPE_VARCHAR2
'** ストアドファンクション実行
session("OraDatabase").ExecuteSql "begin :ret := sak.GetTmp(); end;"
'** 戻り値取得
response.write("<P>" & pret.value & "</P>")
'** パラメタ解消
session("OraDatabase").Parameters.Remove "ret"
・CreateSql での実行
Dim pret
'** SQL 作成
Set session("OraSqlStmt") = session("OraDatabase").CreateSql("begin :ret := sak.GetTmp(); end;" _
, ORASQL_DEFAULT)
'** パラメタ追加
session("OraDatabase").Parameters.Add "ret", 0, ORAPARM_OUTPUT
set pret = session("OraDatabase").Parameters("ret")
pret.ServerType = ORATYPE_VARCHAR2
'** ストアドファンクション実行
session("OraSqlStmt").Refresh
'** 戻り値取得
response.write("<P>" & pret.value & "</P>")
'** パラメタ解消
session("OraDatabase").Parameters.Remove "ret"
'** パラメタクエリ解消
Set session("OraSqlStmt") = Nothing
■補足
・戻り値以外の入力、出力、入出力パラメタも通常のバインド変数でアクセス
すれば良い。"begin :ret := sak.GetTmp(:para1, :para2); end;"
・戻り値がない場合は、"begin sak.GetTmp(:para1, :para2); end;" となる。
・ストアドの実行に限らず、begin ... end; の PL/SQL ブロックを処理する
ことができる。begin ... end; でまとめられるものは、一度に発行した方
がレスポンスは良い。
■現実的なコード例
<%@ Language=VBScript %>
<%
'=======================================================================
' 準備
'=======================================================================
Public Const ORADB_DEFAULT = &H0
Public Const ORASQL_DEFAULT = &H0
Public Const ORASQL_NO_AUTOBIND = &H1
Public Const ORASQL_FAILEXEC = &H2
Public Const ORAPARM_INPUT = 1
Public Const ORAPARM_OUTPUT = 2
Public Const ORAPARM_BOTH = 3
Public Const ORATYPE_VARCHAR2 = 1
Public Const ORATYPE_NUMBER = 2
Public Const ORATYPE_SINT = 3
Public Const ORATYPE_FLOAT = 4
Public Const ORATYPE_STRING = 5
Public Const ORATYPE_VARCHAR = 9
Public Const ORATYPE_DATE = 12
Public Const ORATYPE_UINT = 68
Public Const ORATYPE_CHAR = 96
Public Const ORATYPE_CHARZ = 97
Public Const ORATYPE_CURSOR = 102
dim dbname
dim cnuser
'** エラートラップ開始
on error resume next
'** サービス、ユーザ設定
dbname = ""
cnuser = "SAK/SAK"
'// Oracle サービス名(別名)、ユーザ・パスワード指定
'** oo4o 接続
if isempty(session("OraSession")) then
Set session("OraSession") = Server.CreateObject("OracleInProcServer.XOraSession")
if err <> 0 then
response.write("<P>データベースに接続出来ません。<BR>" _
& "CreateObject - Oracle oo4o エラー</P>")
end if
end if
if isempty(session("OraDatabase")) then
Set session("OraDatabase") = session("OraSession").OpenDatabase(dbname, cnuser, ORADB_DEFAULT)
if err <> 0 then
response.write("<P>データベースに接続出来ません。<BR>" _
& err & ": " & error & "</P>")
end if
end if
'** SQL 作成
if isobject(session("OraSQLStmt")) = false then
Set session("OraSqlStmt") = session("OraDatabase").CreateSql("begin :ret := sak.GetTmp(); end;" _
, ORASQL_DEFAULT)
if session("OraDatabase").LastServerErr = 1008 then session("OraDatabase").LastServerErrReset
if err <> 0 or session("OraDatabase").LastServerErr <> 0 then
response.write("<P>SQL 作成に失敗しました。<BR>" _
& err & ": " & error & "<BR>" _
& "oo4o: " & session("OraDatabase").LastServerErrText & "</P>")
end if
end if
'** パラメタ追加
if isempty(session("ParaAdd")) then
session("OraDatabase").Parameters.Add "ret", 0, ORAPARM_OUTPUT
session("OraDatabase").Parameters("ret").ServerType = ORATYPE_VARCHAR2
if err <> 0 or session("OraDatabase").LastServerErr <> 0 then
response.write("<P>パラメタ追加に失敗しました。<BR>" _
& err & ": " & error & "<BR>" _
& "oo4o: " & session("OraDatabase").LastServerErrText & "</P>")
else
session("ParaAdd") = true
end if
end if
'** エラートラップ終了
on error goto 0
'=======================================================================
' 処理
'=======================================================================
'---- ExecuteSql での実行 ----
response.write("<P>-- ExecuteSql での実行 --</P>")
'** ストアドファンクション実行
session("OraDatabase").ExecuteSql "begin :ret := sak.GetTmp(); end;"
'** 戻り値取得
response.write("<P>" & session("OraDatabase").Parameters("ret").value & "</P>")
'** レコードセットクローズ
set rs = Nothing
'---- CreateSql での実行 ----
response.write("<P>-- CreateSql での実行 --</P>")
'** ストアドファンクション実行
session("OraSqlStmt").Refresh
'** 戻り値取得
response.write("<P>" & session("OraDatabase").Parameters("ret").value & "</P>")
response.write("<P>-- 終了 --</P>")
%>
■ASP VB Script oo4o + SQL 応用編資料
■ASP VB Script ADO + SQL 応用編資料
■ASP VB Script 基礎実地編資料
■ASP VB Script 基礎編資料
■SQL 基礎編資料
■SQL 基礎実地編資料
■SQL チューニング編資料
■Oracle PL/SQL 編資料
■PostgreSQL 編、JAVA Servlet、JSP 編資料
■MySQL 編資料
Copyright (C) 1999-2024 Y.SAK